How can I use OCCT in a Qt Creator project?

Hello, you are doing everything correct. It is a old OCCT bug with CMake.

There a few options to fix:

- Modify CMake Configuration inside your installations 

- link OCCT manually without CMake

- rebuild OCCT locally.

That and other CMake bugs are target for 7.9. version. We plan to reorginize CMake to be valid on the most scenarios.

Best regards, Commenter-1.

Hi,

Could you elaborate please? I'm trying to compile an app with cmake without any success with "No rule to make target '/usr/lib/TKernel.lib'" error.
What should I change in cmake configuration inside my installation?

Not important anymore. Ditched cmake and get working setup with manually listing libraries to link.

hello,
could you teach me how to get working setup with manually listing libraries to link. Should I use ".pro" file?
Thanks.

Heres a copy of my .pro file. It's a bit hard-coded/scrappy in places, but quite frankly it does fine for development. I'm using AssImp, Eigen and TBB which you may not need.

QT       += core gui opengl openglwidgets

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

DEFINES += _DEBUG

TARGET = myApp
TEMPLATE = app

win32-g++ {
message("windows")
ASSIMP_INC_PATH = "C:\sandbox\assimp\include"
ASSIMP_INC_PATH += "C:\sandbox\assimp\build\include"
ASSIMP_LIB_PATH = "C:\sandbox\assimp\build\lib"
ASSIMP_LIB_PATH2 = "C:\sandbox\assimp\build\contrib\zlib"

EIGEN_INC_PATH = "C:\sandbox\eigen-3.4.0"

OCC_INC_PATH = "C:\sandbox\OCCT-7_9_0\buildtbb\inc"
OCC_LIB_PATH = "C:\sandbox\OCCT-7_9_0\buildtbb\win64\gcc\lib"

CAS_INC_DIR = $$OCC_INC_PATH
CAS_LIB_DIR = $$OCC_LIB_PATH
}

unix {
message("Linux")
ASSIMP_INC_PATH = "/home/mmaher/sandbox/assimp/include"
ASSIMP_INC_PATH += "/home/mmaher/sandbox/assimp/build/include"
ASSIMP_LIB_PATH = "/home/mmaher/sandbox/assimp/build/lib"
ASSIMP_LIB_PATH2 = "/home/mmaher/sandbox/assimp/build/contrib/zlib"

OCC_INC_PATH = "/home/mmaher/sandbox/OCCT-7_9_0/build/include/opencascade"
OCC_LIB_PATH = "/home/mmaher/sandbox/OCCT-7_9_0/build/lin64/gcc/libd"
}

OCC_LIBS =      \
#               -lTKDEIGES -lTKDESTL -lTKDEVRML -lTKDESTEP -lTKDEOBJ \
                -lTKShHealing -lTKHLR -lTKTopAlgo -lTKMesh -lTKPrim \
                -lTKCDF -lTKBool -lTKBO -lTKFillet -lTKOffset -lTKLCAF -lTKXCAF \
                -lTKDE -lTKBinXCAF -lTKRWMesh -lTKDEGLTF  \
                -lTKBRep -lTKGeomBase -lTKGeomAlgo -lTKG3d -lTKG2d -lTKXSBase \
                -lTKernel -lTKMath -lTKService -lTKV3d -lTKOpenGl
ASSIMP_LIBS =   -lassimp -lzlibstatic
TBB_LIBS =      -ltbb12 -ltbbmalloc

# major, minor
VERSION = 1.0
DEFINES += VERSION_STRING=\\\"$${VERSION}\\\"

BINARYPATH = $$PWD/binaries/
DESTDIR = $$BINARYPATH/$$DESTINATION_PATH

BUILDPATH = $$PWD/build/
OBJECTS_DIR = $$BUILDPATH/$$DESTINATION_PATH/.obj
MOC_DIR = $$BUILDPATH/$$DESTINATION_PATH/.moc
RCC_DIR = $$BUILDPATH/$$DESTINATION_PATH/.qrc
UI_DIR = $$BUILDPATH/$$DESTINATION_PATH/.ui

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

CONFIG += c++17
CONFIG(release, debug|release) {
    DEFINES += QT_NO_DEBUG_OUTPUT QT_NO_DEBUG
    msvc{
        QMAKE_CFLAGS = /O2
        QMAKE_CXXFLAGS = /O2
        }
    else{
        QMAKE_CFLAGS -= -O2
        QMAKE_CFLAGS -= -O1
        QMAKE_CXXFLAGS -= -O2
        QMAKE_CXXFLAGS -= -O1
        QMAKE_CFLAGS = -m64 -O3
        QMAKE_LFLAGS = -m64 -O3
        QMAKE_CXXFLAGS = -m64 -O3
    }
}

HEADERS += \
    src/Engine/PhysicsEngine.h \
    src/Engine/meshconstraint.h \
    src/Engine/physicsIntersectBox.h \
    src/Engine/physicsMesh.h \
    src/Engine/sceneconfiguration.h \
    src/Engine/tbbTasks.h \
    src/Helpers/filesystem.h \
    src/Helpers/globals.h \
    src/Visuals/CutShape.h \
    src/Visuals/File2D.h \
    src/Visuals/Line2d.h \
    src/Visuals/canvas.h \
    src/Visuals/mainWindow.h \
    src/Visuals/manequin.h \
    src/Visuals/occview.h \
    src/Visuals/occviewenums.h \
    src/Visuals/occwindow.h \
    src/Visuals/selectowner.h \
    src/Visuals/settings.h \
    src/Visuals/stitchline.h \
    src/Visuals/stretchline.h


SOURCES += \
    src/Engine/PhysicsEngine.cpp \
    src/Engine/meshconstraint.cpp \
    src/Engine/physicsIntersectBox.cpp \
    src/Engine/physicsMesh.cpp \
    src/Engine/sceneconfiguration.cpp \
    src/Engine/tbbTasks.cpp \
    src/Helpers/filesystem.cpp \
    src/Visuals/CutShape.cpp \
    src/Visuals/File2D.cpp \
    src/Visuals/Line2d.cpp \
    src/Visuals/canvas.cpp \
    src/Visuals/canvas_bendmode.cpp \
    src/Visuals/canvas_editmode.cpp \
    src/Visuals/canvas_selectmode.cpp \
    src/Visuals/canvas_stitchmode.cpp \
    src/Visuals/main.cpp \
    src/Visuals/mainWindow.cpp \
    src/Visuals/manequin.cpp \
    src/Visuals/occview.cpp \
    src/Visuals/occwindow.cpp \
    src/Visuals/selectowner.cpp \
    src/Visuals/settings.cpp \
    src/Visuals/stitchline.cpp \
    src/Visuals/stretchline.cpp

RESOURCES += \
    res/icons.qrc

win32 {
    DEFINES += WNT
}

INCLUDEPATH += $${OCC_INC_PATH} $${EIGEN_INC_PATH} $${ASSIMP_INC_PATH}
LIBS += -L$${OCC_LIB_PATH} -L$${ASSIMP_LIB_PATH} -L$${ASSIMP_LIB_PATH2}
LIBS += $${OCC_LIBS} $${ASSIMP_LIBS} $${TBB_LIBS}